Breakout on NES

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

// Casse-briques — NES
//
// Les règles sont dans Examples/common/CasseBriques/Jeu.s8u, les mêmes sur toutes les machines.
// Ici, l'affichage de la NES : les briques en tuiles, la balle et la raquette en sprites.
// Manette : gauche, droite, A pour lancer la balle. Sans manette, la démo joue.
architecture nintendo.nes;

addlib ppu.base;
addlib ppu.screentext;
addlib ppu.sprite;
addlib io.base;

addunit "../../../common/CasseBriques/Jeu.s8u";   // les règles, communes
addunit "Ecran.s8u";                                // l'affichage de la NES

unit {
    main() {
        Jeu.jouer();
    }
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143

// Ecran.s8u : l'affichage du casse-briques sur NES.
//
// La NES affiche une carte de tuiles de 8 x 8 points (la nametable) et 64 sprites de 8 x 8 :
//   - les briques et les murs sont des tuiles, dessinées ici, de 4 couleurs (2 bits par point) ;
//   - la palette ne se choisit que par bloc de 32 x 32 points : quatre rangées de briques
//     partagent la même. La couleur de chaque brique vient donc de sa tuile (couleur 1, 2 ou 3) ;
//   - la balle est un sprite, la raquette trois sprites côte à côte.
unit Ecran {
    // Le terrain de 160 x 144 points, colonne 8 et ligne 6 : ses bords tombent sur les blocs de
    // palette (32 x 32 points), les murs sont dans des blocs à part
    const ubyte COL0 = 8;
    const ubyte LIG0 = 6;
    const ubyte X0 = 64;
    const ubyte Y0 = 48;

    // Les tuiles du fond : 16 octets chacune, le plan 0 puis le plan 1 (bit 7 = point de gauche).
    // 1 à 3 : la moitié gauche d'une brique de couleur 1, 2, 3 ; 4 à 6 : la moitié droite (avec
    // l'écart d'un point) ; 7 : le mur, de couleur 3
    const ubyte TUILES[112] = {
        0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0x00,   0, 0, 0, 0, 0, 0, 0, 0,                         // 1
        0, 0, 0, 0, 0, 0, 0, 0,   0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0x00,                         // 2
        0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0x00,   0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0x00, // 3
        0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0x00,   0, 0, 0, 0, 0, 0, 0, 0,                         // 4
        0, 0, 0, 0, 0, 0, 0, 0,   0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0x00,                         // 5
        0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0x00,   0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0xFE, 0x00, // 6
        0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF,   0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF  // 7
    };
    // Les tuiles des sprites : 0 la balle (4 x 4 points), 1 un morceau de raquette (8 x 4)
    const ubyte TUILES_SPRITES[32] = {
        0x60, 0xF0, 0xF0, 0x60, 0, 0, 0, 0,   0, 0, 0, 0, 0, 0, 0, 0,
        0xFF, 0xFF, 0xFF, 0xFF, 0, 0, 0, 0,   0, 0, 0, 0, 0, 0, 0, 0
    };

    void init() {
        ppu.initText();
        ppu.loadTiles(@.TUILES, 1, 7);
        sprite.loadTiles(@.TUILES_SPRITES, 0, 2);
        ppu.setBackgroundColor(ppu.BLACK);
        ppu.setPalette(0, 1, ppu.WHITE);            // le texte
        ppu.setPalette(0, 3, ppu.GREY);             // les murs
        ppu.setPalette(1, 1, ppu.RED);              // les quatre premières rangées
        ppu.setPalette(1, 2, ppu.ORANGE);
        ppu.setPalette(1, 3, ppu.YELLOW);
        ppu.setPalette(2, 1, ppu.GREEN);            // la dernière rangée
        ppu.setPalette(2, 2, ppu.LIGHT_GREEN);
        ppu.setPalette(2, 3, ppu.LIGHT_BLUE);
        ppu.setPalette(4, 1, ppu.WHITE);            // les sprites
        // une palette par bloc de 32 x 32 points : les blocs des briques
        for (byte bx = 2; bx < 7; bx++) {
            ppu.setAreaPalette(bx, 2, 1);
            ppu.setAreaPalette(bx, 3, 2);
        }
        // les murs
        for (ubyte l = 5; l < 24; l++) {
            ppu.putTile(7, (byte)l, 7);
            ppu.putTile(28, (byte)l, 7);
        }
        for (ubyte c = 7; c < 29; c++) {
            ppu.putTile((byte)c, 5, 7);
        }
        // la balle et les trois morceaux de raquette
        sprite.set(0, 0, 240, 0);
        sprite.set(1, 0, 240, 1);
        sprite.set(2, 0, 240, 1);
        sprite.set(3, 0, 240, 1);
        for (byte n = 0; n < 4; n++) {
            sprite.setAttributes(n, 0, 0);          // palette de sprites 0, devant le fond
        }
    }

    void attendreImage() {
        ppu.on();
        ppu.waitFrame();
    }

    ubyte manette() {
        ubyte t = 0;
        io.readJoysticks();
        if (io.isDirPressed(0, io.JOY_LEFT) != 0) {
            t = t | Jeu.GAUCHE;
        }
        if (io.isDirPressed(0, io.JOY_RIGHT) != 0) {
            t = t | Jeu.DROITE;
        }
        if (io.isPressed(0, io.JOY_A) != 0) {
            t = t | Jeu.BOUTON;
        }
        return t;
    }

    // 100 tuiles d'un coup : l'écran est éteint le temps de les poser
    void dessinerBriques() {
        ppu.off();
        for (ubyte l = 0; l < 5; l++) {
            for (ubyte c = 0; c < 10; c++) {
                ubyte couleur = (ubyte)((c + l) % 3);               // 0, 1 ou 2
                ubyte x = (ubyte)(.COL0 + c * 2);
                ubyte y = (ubyte)(.LIG0 + 2 + l);
                ppu.putTile((byte)x, (byte)y, (ubyte)(1 + couleur));
                ppu.putTile((byte)(x + 1), (byte)y, (ubyte)(4 + couleur));
            }
        }
    }

    // Effacer une brique : deux tuiles d'espace (32), posées à l'image suivante
    void effacerBrique(ubyte c, ubyte l) {
        ubyte x = (ubyte)(.COL0 + c * 2);
        ubyte y = (ubyte)(.LIG0 + 2 + l);
        ppu.putTile((byte)x, (byte)y, 32);
        ppu.putTile((byte)(x + 1), (byte)y, 32);
    }

    void placer(ubyte raquette, ubyte x, ubyte y) {
        ubyte ry = (ubyte)(.Y0 + Jeu.RAQUETTE_Y);
        ubyte rx = (ubyte)(.X0 + raquette);
        sprite.move(1, rx, ry);
        sprite.move(2, (ubyte)(rx + 8), ry);
        sprite.move(3, (ubyte)(rx + 16), ry);
        if (y < Jeu.HAUTEUR) {
            sprite.move(0, (ubyte)(.X0 + x), (ubyte)(.Y0 + y));
        } else {
            sprite.move(0, 0, 240);                  // sortie par le bas : cachée
        }
    }

    void afficherInfos() {
        ppu.setCursor(8, 3);
        ppu.print("SCORE ");
        ppu.print(@Jeu.texteScore);
        ppu.setCursor(21, 3);
        ppu.print("VIES ");
        ppu.putChar((ubyte)('0' + Jeu.vies));
    }

    void message(uint texte) {
        ppu.setCursor(15, 17);
        if (texte == 0) {
            ppu.print("     ");
            return;
        }
        ppu.print(texte);
    }
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310

// Jeu.s8u : les règles du casse-briques, les mêmes sur toutes les machines.
//
// Aucune ligne `architecture` : cette unit est compilée pour la machine du programme. Elle ne
// connaît que l'unit Ecran, que chaque machine écrit à sa façon (tuiles, sprites, bitmap…) :
//
//   Ecran.init()                     préparer l'écran
//   Ecran.attendreImage()            attendre l'image suivante
//   Ecran.manette()                  les touches : GAUCHE, DROITE, BOUTON
//   Ecran.dessinerBriques()          dessiner toutes les briques (Jeu.briques)
//   Ecran.effacerBrique(c, l)        effacer la brique de la colonne c, rangée l
//   Ecran.placer(raquette, x, y)     placer la raquette et la balle
//   Ecran.afficherInfos()            écrire le score et les vies (Jeu.texteScore, Jeu.vies)
//   Ecran.message(texte)             écrire un message au milieu, 0 pour l'effacer
//
// Le terrain fait 160 x 144 points ; chaque machine le place où elle veut sur son écran.
unit Jeu {
    // Le terrain
    const ubyte LARGEUR = 160;
    const ubyte HAUTEUR = 144;

    // Les briques : 10 colonnes de 16 points, 5 rangées de 8 points. 16 et 8 sont des
    // puissances de deux : la case d'un point se calcule par des décalages (x >> 4, y >> 3).
    const ubyte COLONNES = 10;
    const ubyte LIGNES = 5;
    const ubyte BRIQUE_L = 16;
    const ubyte BRIQUE_H = 8;
    const ubyte HAUT_BRIQUES = 16;              // le haut de la première rangée
    const ubyte BAS_BRIQUES = 56;               // HAUT_BRIQUES + LIGNES * BRIQUE_H
    const ubyte DEBUT_LIGNE[] = { 0, 10, 20, 30, 40 };   // une table plutôt qu'une multiplication
    const uint POINTS[] = { 50, 40, 30, 20, 10 };        // les rangées du haut valent plus

    // La raquette et la balle
    const ubyte RAQUETTE_Y = 132;
    const ubyte RAQUETTE_L = 24;
    const ubyte RAQUETTE_H = 4;
    const ubyte BALLE = 4;                      // la balle est un carré de 4 points

    // Les touches, rendues par Ecran.manette()
    const ubyte GAUCHE = 1;
    const ubyte DROITE = 2;
    const ubyte BOUTON = 4;

    // La démo vise un endroit différent de la raquette à chaque rebond : l'angle change, et la
    // balle ne tourne pas en rond dans une zone déjà vide
    const byte VISEES[] = { -9, 6, -3, 9, -6, 3 };

    ubyte briques[50];          // 1 : la brique est là
    ubyte restantes;            // briques encore debout
    ubyte vies;
    uint score;
    ubyte texteScore[6];        // le score en chiffres, pour Ecran.afficherInfos()

    int balleX;
    int balleY;
    int dx;                     // la vitesse de la balle, en points par image
    int dy;
    int raquetteX;
    ubyte collee;               // 1 : la balle attend sur la raquette
    ubyte attente;              // images avant le lancement automatique
    ubyte inactif;              // images sans toucher la manette : la démo prend la main
    ubyte visee;                // la visée de la démo, dans VISEES

    ubyte colonneTouchee;       // la brique trouvée par briqueEn()
    ubyte ligneTouchee;

    // ---------------------------------------------------------------------------------------
    // La boucle du jeu : appelée une fois par main(), ne revient jamais
    void jouer() {
        Ecran.init();
        nouvellePartie();
        while (1) {
            Ecran.attendreImage();
            image(Ecran.manette());
            Ecran.placer((ubyte).raquetteX, (ubyte).balleX, (ubyte).balleY);
        }
    }

    // ---------------------------------------------------------------------------------------
    // Une partie, une balle
    void nouvellePartie() {
        for (ubyte n = 0; n < 50; n++) {
            .briques[n] = 1;
        }
        .restantes = 50;
        .vies = 3;
        .score = 0;
        .inactif = 255;             // la démo joue tant que personne ne touche la manette
        Ecran.dessinerBriques();
        majInfos();
        nouvelleBalle();
    }

    void nouvelleBalle() {
        .raquetteX = 68;            // au milieu : (160 - 24) / 2
        .collee = 1;
        .attente = 60;              // une seconde avant le lancement automatique
        coller();
    }

    // La balle posée sur la raquette, en son milieu
    void coller() {
        .balleX = .raquetteX + 10;
        .balleY = .RAQUETTE_Y - .BALLE;
    }

    // ---------------------------------------------------------------------------------------
    // Une image de jeu
    void image(ubyte touches) {
        bougerRaquette(touches);
        if (.collee == 1) {
            coller();
            if (.attente > 0) {
                .attente--;
            }
            if ((touches & .BOUTON) != 0 || .attente == 0) {
                .collee = 0;
                .dx = 1;
                .dy = -2;
            }
            return;
        }
        deplacerBalle();
        if (.balleY >= .HAUTEUR) {
            ballePerdue();
        }
    }

    // La raquette : les touches, ou la démo quand personne ne joue
    void bougerRaquette(ubyte touches) {
        if (touches != 0) {
            .inactif = 0;
        } else if (.inactif < 255) {
            .inactif++;
        }
        if (.inactif > 120) {
            // la démo : la raquette suit la balle
            int cible = .balleX + 2 - .VISEES[.visee];
            if (.raquetteX + 12 < cible - 1) {
                touches = .DROITE;
            } else if (.raquetteX + 12 > cible + 1) {
                touches = .GAUCHE;
            }
        }
        if ((touches & .GAUCHE) != 0 && .raquetteX > 0) {
            .raquetteX = .raquetteX - 2;
        }
        if ((touches & .DROITE) != 0 && .raquetteX < .LARGEUR - .RAQUETTE_L) {
            .raquetteX = .raquetteX + 2;
        }
    }

    // ---------------------------------------------------------------------------------------
    // La balle : on avance en x, puis en y, et on regarde à chaque fois ce que touche le bord
    // de la balle qui avance
    void deplacerBalle() {
        int x = .balleX + .dx;
        int y;
        int bord;

        // les murs de gauche et de droite
        if (x < 0) {
            x = 0;
            .dx = -.dx;
        } else if (x > .LARGEUR - .BALLE) {
            x = .LARGEUR - .BALLE;
            .dx = -.dx;
        }
        // les briques, en x : le bord gauche ou droit de la balle, en haut et en bas
        bord = x;
        if (.dx > 0) {
            bord = x + .BALLE - 1;
        }
        if (toucher(bord, .balleY) != 0 || toucher(bord, .balleY + .BALLE - 1) != 0) {
            .dx = -.dx;
            x = .balleX;
        }
        .balleX = x;

        // le plafond
        y = .balleY + .dy;
        if (y < 0) {
            y = 0;
            .dy = -.dy;
        }
        // les briques, en y : le bord haut ou bas de la balle, à gauche et à droite
        bord = y;
        if (.dy > 0) {
            bord = y + .BALLE - 1;
        }
        if (toucher(.balleX, bord) != 0 || toucher(.balleX + .BALLE - 1, bord) != 0) {
            .dy = -.dy;
            y = .balleY;
        }
        .balleY = y;

        rebondRaquette();
    }

    // La raquette : la balle descend et chevauche la raquette
    void rebondRaquette() {
        int zone;
        if (.dy < 0) {
            return;
        }
        if (.balleY + .BALLE < .RAQUETTE_Y || .balleY > .RAQUETTE_Y + .RAQUETTE_H) {
            return;
        }
        if (.balleX + .BALLE <= .raquetteX || .balleX >= .raquetteX + .RAQUETTE_L) {
            return;
        }
        // l'endroit touché donne l'angle : le milieu de la balle sur l'une des 4 zones de
        // 6 points de la raquette. Trois comparaisons, pas de division par 6
        zone = .balleX + 2 - .raquetteX;
        if (zone < 6) {
            .dx = -2;
        } else if (zone < 12) {
            .dx = -1;
        } else if (zone < 18) {
            .dx = 1;
        } else {
            .dx = 2;
        }
        .dy = -2;
        .balleY = .RAQUETTE_Y - .BALLE;
        .visee++;
        if (.visee == 6) {
            .visee = 0;
        }
    }

    // ---------------------------------------------------------------------------------------
    // Les collisions avec les briques : la grille, sans regarder l'écran

    // La brique sous le point (x, y), ou 255 s'il n'y en a pas
    ubyte briqueEn(int x, int y) {
        ubyte n;
        if (y < .HAUT_BRIQUES || y >= .BAS_BRIQUES || x < 0 || x >= .LARGEUR) {
            return 255;
        }
        .colonneTouchee = (ubyte)(x >> 4);                     // x / 16
        .ligneTouchee = (ubyte)((y - .HAUT_BRIQUES) >> 3);     // (y - 16) / 8
        n = (ubyte)(.DEBUT_LIGNE[.ligneTouchee] + .colonneTouchee);
        if (.briques[n] == 0) {
            return 255;
        }
        return n;
    }

    // Casse la brique sous le point (x, y) s'il y en a une ; rend 1 si la balle a touché
    ubyte toucher(int x, int y) {
        ubyte n = briqueEn(x, y);
        if (n == 255) {
            return 0;
        }
        .briques[n] = 0;
        .restantes--;
        .score = .score + .POINTS[.ligneTouchee];
        Ecran.effacerBrique(.colonneTouchee, .ligneTouchee);
        majInfos();
        if (.restantes == 0) {
            gagne();
        }
        return 1;
    }

    // ---------------------------------------------------------------------------------------
    // Perdre une balle, gagner, attendre

    void ballePerdue() {
        .vies--;
        majInfos();
        if (.vies == 0) {
            Ecran.message("PERDU");
            pause(150);
            Ecran.message(0);
            nouvellePartie();
            return;
        }
        nouvelleBalle();
    }

    void gagne() {
        Ecran.message("BRAVO");
        pause(150);
        Ecran.message(0);
        for (ubyte n = 0; n < 50; n++) {
            .briques[n] = 1;
        }
        .restantes = 50;
        Ecran.dessinerBriques();
        nouvelleBalle();
    }

    void pause(ubyte images) {
        for (ubyte i = 0; i < images; i++) {
            Ecran.attendreImage();
        }
    }

    // Le score en chiffres dans texteScore (5 chiffres et le 0 de fin), puis l'affichage
    void majInfos() {
        uint v = .score;
        for (ubyte i = 5; i > 0; i--) {
            .texteScore[i - 1] = (ubyte)('0' + v % 10);
            v = v / 10;
        }
        .texteScore[5] = 0;
        Ecran.afficherInfos();
    }
}